Obsah

# REGEX

Nalezne a vrátí nebo volitelně nahradí text za použití regulárních výrazů.

### Syntaxe

REGEX( Text ; Výraz [ ; [ Náhrada ] [ ; Přepínače|Výskyt ] ] )

Text: Text nebo odkaz na buňku, na který se má regulární výraz použít.

Výraz: Text představující regulární výraz ve tvaru podle projektu ICU. Není-li nalezena shoda a není zadána Náhrada, funkce vrátí #N/A.

Náhrada: Nepovinné. Text náhrady a odkazy na očíslované skupiny. Není-li nalezena shoda, Text se vrátí nezměněný.

Přepínače: Nepovinné. Přepínač "g" nahradí všechny výskyty Výrazu v Textu. Není-li nalezena shoda, Text se vrátí nezměněný.

Výskyt: Nepovinné. Číslo udávající, kolikátá shoda Výrazu v Textu se má najít nebo nahradit. Není-li nalezena shoda a není zadána Náhrada, funkce vrátí #N/A. Není-li nalezena shoda a Náhrada je zadána, funkce vrátí nezměněný Text. Je-li Výskyt číslo 0, funkce vrátí nezměněný Text.

### Příklady

=REGEX("123456ABCDEF";"[:digit:]";"Z") vrátí "Z23456ABCDEF", první výskyt číslice je nahrazen písmenem "Z".

=REGEX("123456ABCDEF";"[:digit:]";"Z";"g") vrátí "ZZZZZZABCDEF", všechny číslice jsou nahrazeny písmenem "Z".

=REGEX("123456ABCDEF";"[126]";"";"g") vrátí "345ABCDEF", všechny výskyty číslic "1", "2" a "6" jsou nahrazeny prázdným řetězcem, tedy smazány.

=REGEX("axbxcxd";".x";;2) vrátí "bx", druhou shodu s výrazem ".x".

=REGEX("axbxcxd";"(.)x";"$1y";2) vrátí "axbycxd", druhá shoda s výrazem "(.)x" (tj. "bx") je nahrazena skupinou mezi závorkami, která obsahuje jeden znak (tj. "b"), za níž následuje "y".

#### Technické informace

Tato funkce je k dispozici od verze LibreOffice 6.2.

Tato funkce není součástí standardu Open Document Format for Office Applications (OpenDocument) Version 1.3. Part 4: Recalculated Formula (OpenFormula) Format. Její jmenný prostor je

ORG.LIBREOFFICE.REGEX

Související témata

Wiki stránka REGEX.

Seznam regulárních výrazů

Regulární výrazy v projektu ICU